Как найти строки в дереве значений 1с

Объект «ДеревоЗначений» в 1С 8.3 представляет собой динамический набор значений любого типа. Для такого набора доступны свойства «колонки» и «строки» где каждая строка может иметь набор подчинённых строк, а каждая подчинённая строка набор своих подчинённых строк и т.д.  Программная инициализация дерева значений в 1С осуществляется с помощью оператора НОВЫЙ.

Пример:

ДеревоЗначений = Новый ДеревоЗначений;

Визуально, объект «ДеревоЗначений» похож на дерево групп справочника. К примеру, можно открыть справочник «Номенклатура» любой типовой конфигурации выставив форму списка в «Режим просмотра» — «Дерево».

Полезно понимать, что объект «ДеревоЗначений» схож с объектом «ТаблицаЗначений». Основной отличительный признак наличие дополнительного реквизита «Родитель» у объекта «ДеревоЗначений», с помощью которого и организовывается иерархия и подчинённость.

Дерево значений на управляемой форме

Если появляется необходимость показать данные в виде дерева пользователю, следует на форме создать реквизит с типом «ДеревоЗначений» и определится с составом колонок.

Для отображения на форме добавим реквизит в раздел элементов формы простым перетаскиванием.

Заполнение дерева значений

Заполнить данными дерево значений в 1С можно программно (вручную) или получить из результата запроса. Рассмотрим на примерах оба способа.

Ручное заполнение реквизита формы с типом «ДеревоЗначений»

Простой пример:

&НаКлиенте
Процедура ДЗ_НаФорме(Команда)
ДЗ_НаФормеНаСервере();
КонецПроцедуры

&НаСервере
Процедура ДЗ_НаФормеНаСервере()

// Преобразуем реквизит формы ДЗ в объект прикладного типа
ДеревоЗначений = РеквизитФормыВЗначение("ДЗ");

Корень = ДеревоЗначений.Строки.Добавить();
Корень.Наименование = "Корневая группа";

Группа1 = Корень.Строки.Добавить();
Группа1.Наименование = "Первая группа";

Элемент1 = Группа1.Строки.Добавить();
Элемент1.Наименование = "Элемент №1";                               

Группа2 = Корень.Строки.Добавить();
Группа2.Наименование = "Втровая группа";

Элемент1 = Группа2.Строки.Добавить();
Элемент1.Наименование = "Элемент №1";

Элемент2 = Группа2.Строки.Добавить();
Элемент2.Наименование = "Элемент №2";
        
// Преобразуем объект ДеревоЗначений в реквизит формы         
ЗначениеВРеквизитФормы(ДеревоЗначений,"ДЗ");                                                                     

КонецПроцедуры

Результат запроса на форме:

Заполнение дерева значений из результата запроса

Сделаем простой запрос к справочнику «Номенклатура». Результат запроса преобразуем в дерево значений с помощью метода «Выгрузить», установив для его параметра «ТипОбхода» в значение «ПоГруппировкамСИерархией».  Для передачи сформированного дерева значений на форму, важно чтобы имена колонок совпадали с именами колонок реквизита на форме.

&НаКлиенте
Процедура ДЗ_НаФорме(Команда)
ДЗ_НаФормеНаСервере();
КонецПроцедуры

&НаСервере
Процедура ДЗ_НаФормеНаСервере()

Запрос = Новый Запрос;
Запрос.Текст =
"ВЫБРАТЬ
|          Номенклатура.Ссылка КАК Наименование
|ИЗ
|          Справочник.Номенклатура КАК Номенклатура
|
|УПОРЯДОЧИТЬ ПО
|          Наименование ИЕРАРХИЯ";
ДеревоЗначений = Запрос.Выполнить().Выгрузить(ОбходРезультатаЗапроса.ПоГруппировкамСИерархией);

ЗначениеВРеквизитФормы(ДеревоЗначений, "ДЗ");

КонецПроцедуры

Результат запроса на форме может выглядеть так:

Поиск строк в дереве значений

Для поиска строк в дереве значений существует два способа, точнее говоря, метода.

Метод «Найти()»

• Найти(<Значение>, <Колонки>, <ВключатьПодчиненные>)

Возвращает строку дерева значений, если строка не найдена, вернёт «Неопределено». Поиск можно ограничивать, указав в параметре <Колонки> нужные колонки для поиска. Также расширять, указав для параметра <ВключатьПодчиненные> значение «Истина», тогда в поиске будут участвовать строки подчинённых коллекций.

Для примера найдём строку со значением «Элемент №1» в дереве значений вида:

Пример кода:

&НаКлиенте
Процедура НайтиСтрокуДЗ(Команда)
            НайтиСтрокуДЗ_НаСервере();
КонецПроцедуры

&НаСервере
Процедура НайтиСтрокуДЗ_НаСервере()

// Преобразуем реквизит формы ДЗ в объект прикладного типа
ДеревоЗначений = РеквизитФормыВЗначение("ДЗ");

// Ищем строку
НайденнаяСтрока = ДеревоЗначений.Строки.Найти("Элемент №1","Наименование", Истина);

// Анализ результата поиска
Если НайденнаяСтрока = Неопределено Тогда
Сообщить("Строка не найдена");
Иначе
Сообщить(НайденнаяСтрока.Наименование + " - " + НайденнаяСтрока.Родитель.Наименование);
КонецЕсли;
          
КонецПроцедуры

Результат:

Из результата видно, что метод вернул первую попавшуюся строку, и поиск был прекращён.

Метод «НайтиСтроки()»

Если необходимо найти все строки со значением «Элемент №1» тогда следует использовать метод НайтиСтроки()

• НайтиСтроки(<ПараметрыОтбора>, <ВключатьПодчиненные>)

Где <ПараметрыОтбора> — это условия для поиска в виде структуры, а параметр <ВключатьПодчиненные> с помощью значений Ложь/Истина контролирует возможность поиска в подчинённых коллекциях.

Пример кода:

&НаКлиенте
Процедура НайтиСтрокиДЗ(Команда)
НайтиСтрокиДЗНаСервере();
КонецПроцедуры

&НаСервере
Процедура НайтиСтрокиДЗНаСервере()

// Преобразуем реквизит формы ДЗ в объект прикладного типа
ДеревоЗначений = РеквизитФормыВЗначение("ДЗ");

// Условие для поиска
ПараметрыОтбора = Новый Структура;
ПараметрыОтбора.Вставить("Наименование", "Элемент №1");

// Поиск строк
МассивСтрок = ДеревоЗначений.Строки.НайтиСтроки(ПараметрыОтбора, Истина);

// Проверяем найдены ли строки
Если МассивСтрок.Количество() = 0 Тогда
Сообщить("Не найдено ни одной строки, удовлетворяющей условия поиска.");
КонецЕсли;

// Перебор массива строк
Для Каждого Строка Из МассивСтрок Цикл

Если Строка.Родитель = Неопределено Тогда
Сообщить(Строка.Наименование + " - Корень дерева значений.");
Иначе
Сообщить(Строка.Наименование + " - " + Строка.Родитель.Наименование);
КонецЕсли

КонецЦикла;

КонецПроцедуры

Результат:

Очистка дерева значений или строк

Для очистки дерева значений пригодятся методы  Очистить(), Удалить(). Пример кода:

&НаСервере
Процедура УдалитьСтрокуНаСервере()

// Преобразуем реквизит формы ДЗ в объект прикладного типа
ДеревоЗначений = РеквизитФормыВЗначение("ДЗ");

ДеревоЗначений.Строки.Очистить();

// Или по индексу
ДеревоЗначений.Строки.Удалить(0);

// Преобразуем объект ДеревоЗначений в реквизит формы
ЗначениеВРеквизитФормы(ДеревоЗначений, "ДЗ");

КонецПроцедуры

С помощью данных методов возможно удаление конкретных строк дерева значений.

!!!При удалении либо очистки строки все её подчинённые строки удалятся!!!

Обход дерева значений в 1С

Обойти все строки дерева значений удобнее всего с помощью рекурсии.  Таким способом мы сможем обойти дерево значений любой вложенности.

Пример:

&НаСервере
Процедура ОбойтиДЗ_НаСервере()
ДеревоЗначений = РеквизитФормыВЗначение("ДЗ");
ОбходДереваЗначений(ДеревоЗначений);
КонецПроцедуры

&НаСервере
Процедура ОбходДереваЗначений(Данные)

Для Каждого Строка Из Данные.Строки Цикл

Сообщить(Строка.Наименование);

Если Строка.Строки.Количество()>0 Тогда
ОбходДереваЗначений(Строка);
КонецЕсли;

КонецЦикла;

КонецПроцедуры

Как преобразовать дерево значений в таблицу значений

Состав элементов и реквизитов формы:

&НаКлиенте
Процедура ВТЗ(Команда)
ВТЗНаСервере();
КонецПроцедуры

&НаСервере
Процедура ВТЗНаСервере()


ДеревоЗначений = РеквизитФормыВЗначение("ДЗ");
ТаблицаЗначений = РеквизитФормыВЗначение("ТЗ");

ПреобразоватьВ_ТЗ(ДеревоЗначений, ТаблицаЗначений, Новый УникальныйИдентификатор("00000000-0000-0000-0000-000000000000"));
ДеревоЗначений.Строки.Очистить();

ЗначениеВРеквизитФормы(ТаблицаЗначений, "ТЗ");
ЗначениеВРеквизитФормы(ДеревоЗначений, "ДЗ");
КонецПроцедуры

&НаСервере
Процедура ПреобразоватьВ_ТЗ(Данные, ТаблицаЗначений, ГУИД)

Для Каждого Строка Из Данные.Строки Цикл

НовСтрока = ТаблицаЗначений.Добавить();
НовСтрока.Наименование = Строка.Наименование;
НовСтрока.Родитель = ГУИД;
НовСтрока.ГУИД = Новый УникальныйИдентификатор();

Если Строка.Строки.Количество()>0 Тогда
ПреобразоватьВ_ТЗ(Строка, ТаблицаЗначений, НовСтрока.ГУИД);
КонецЕсли;

КонецЦикла;

КонецПроцедуры

Используя данный способ можно легко преобразовать таблицу значений обратно в дерево значений.  Из примера «ГУИД» это уникальный идентификатор строки, а «Родитель» уникальный идентификатор родителя. Если обратного преобразования не требуется можно исключить использование колонок «Родитель» и  «ГУИД».

Дерево значений представляет из себя некую структуру с иерархией. Каждая строка имеет свойства «Родитель» и «Строки». У каждой строки может быть сколько угодно подчиненных строк. При этом такие операции как поиск, сортировка, подсчет итогов можно проводить с учетом уровня иерархии и подчиненных строк.

Программное создание дерева значений

Как уже упоминалось выше, каждая строка имеет свойство Строки, которое содержит коллекцию дочерних строк. И сам объект ДеревоЗначений имеет свойство Строки, которое содержит коллекцию строк верхнего уровня.

&НаКлиенте
Процедура СоздатьДеревоЗначений(Команда)
    СоздатьДеревоЗначенийНаСервере();
КонецПроцедуры

&НаСервере
Процедура СоздатьДеревоЗначенийНаСервере()

    // создаем объект ДеревоЗначений и добавляем колонки
    ДеревоЗначений = Новый ДеревоЗначений();
    ДеревоЗначений.Колонки.Добавить("Код");
    ДеревоЗначений.Колонки.Добавить("Наименование");
    ДеревоЗначений.Колонки.Добавить("Количество");

    // добавляем две строки верхнего уровня
    ГруппаТовары = ДеревоЗначений.Строки.Добавить();
    ГруппаТовары.Код = "001";
    ГруппаТовары.Наименование = "Товары";
    ГруппаТовары.Количество = "";
    ГруппаУслуги = ДеревоЗначений.Строки.Добавить();
    ГруппаУслуги.Код = "002";
    ГруппаУслуги.Наименование = "Услуги";
    ГруппаУслуги.Количество = "";

    // для первой строки верхнего уровня добавляем дочерние строки
    ПервыйТовар = ГруппаТовары.Строки.Добавить();
    ПервыйТовар.Код = "003";
    ПервыйТовар.Наименование = "Первый товар";
    ПервыйТовар.Количество = 5;
    ПервыйТовар = ГруппаТовары.Строки.Добавить();
    ПервыйТовар.Код = "004";
    ПервыйТовар.Наименование = "Второй товар";
    ПервыйТовар.Количество = 7;

    // для второй строки верхнего уровня добавляем дочерние строки
    ПерваяУслуга = ГруппаУслуги.Строки.Добавить();
    ПерваяУслуга.Код = "005";
    ПерваяУслуга.Наименование = "Первая услуга";
    ПерваяУслуга.Количество = "";
    ВтораяУслуга = ГруппаУслуги.Строки.Добавить();
    ВтораяУслуга.Код = "006";
    ВтораяУслуга.Наименование = "Вторая услуга";
    ВтораяУслуга.Количество = "";

    // цикл по строкам верхнего уровня
    Для Каждого ТекущаяГруппа Из ДеревоЗначений.Строки Цикл
        Сообщить("Код: " + ТекущаяГруппа.Код + ", Группа: " + ТекущаяГруппа.Наименование);
        // цикл по дочерним строкам текущей строки верхнего уровня
        Для Каждого ТекущийТоварИлиУслуга Из ТекущаяГруппа.Строки Цикл
            Сообщить(
                "Код: " + ТекущийТоварИлиУслуга.Код +
                ", Товар или услуга: " + ТекущийТоварИлиУслуга.Наименование
            );
        КонецЦикла;
    КонецЦикла;

КонецПроцедуры

Код: 001, Группа: Товары
Код: 003, Товар или услуга: Первый товар
Код: 004, Товар или услуга: Второй товар
Код: 002, Группа: Услуги
Код: 005, Товар или услуга: Первая услуга
Код: 006, Товар или услуга: Вторая услуга

КоллекцияКолонокДереваЗначений.Добавить(Имя, Тип, Заголовок, Ширина) 

КоллекцияСтрокДереваЗначений.Добавить()

Заполнить табличное поле на форме

Визуальное представление дерева значений на форме обеспечивает элемент Таблица.

Пример программного заполнения дерева значений для управляемых форм:

&НаКлиенте
Процедура ЗаполнитьТабличноеПоле(Команда)
    ЗаполнитьТабличноеПолеНаСервере();
КонецПроцедуры

&НаСервере
Процедура ЗаполнитьТабличноеПолеНаСервере()
    ДеревоЗначений = РеквизитФормыВЗначение("РеквизитДеревоЗначений");

    // Добавляем строку в корень дерева
    ПерваяСтрока = ДеревоЗначений.Строки.Добавить();
    ПерваяСтрока.ПерваяКолонка = "Первая строка, первая колонка";
    ПерваяСтрока.ВтораяКолонка = "Первая строка, вторая колонка";
    // Дочерняя строка первой строки
    ВтораяСтрока = ПерваяСтрока.Строки.Добавить();
    ВтораяСтрока.ПерваяКолонка = "Вторая строка, первая колонка";
    ВтораяСтрока.ВтораяКолонка = "Вторая строка, вторая колонка";
    // Дочерняя строка второй строки
    ТретьяСтрока = ВтораяСтрока.Строки.Добавить();
    ТретьяСтрока.ПерваяКолонка = "Третья строка, первая колонка";
    ТретьяСтрока.ВтораяКолонка = "Третья строка, вторая колонка";

    ЗначениеВРеквизитФормы(ДеревоЗначений, "РеквизитДеревоЗначений");
КонецПроцедуры

Результат выполнения запроса очень легко преобразовать в дерево значений, для этого нужно воспользоваться методом Выгрузить() и указать параметр ТипОбхода отличным от того, что стоит по умолчанию, т.е. ПоГруппировкам или ПоГруппировкамСИерархией.

&НаКлиенте
Процедура ЗаполнитьТабличноеПоле(Команда)
    ЗаполнитьТабличноеПолеНаСервере();
КонецПроцедуры

&НаСервере
Процедура ЗаполнитьТабличноеПолеНаСервере()
    Запрос = Новый Запрос();
    Запрос.Текст = 
        "ВЫБРАТЬ
        |    Номенклатура.Наименование КАК ПерваяКолонка,
        |    Номенклатура.Код КАК ВтораяКолонка
        |ИЗ
        |    Справочник.Номенклатура КАК Номенклатура
        |УПОРЯДОЧИТЬ ПО
        |    ПерваяКолонка ИЕРАРХИЯ";
    ДеревоЗначений = Запрос.Выполнить().Выгрузить(
        ОбходРезультатаЗапроса.ПоГруппировкамСИерархией
    );
    ЗначениеВРеквизитФормы(ДеревоЗначений, "РеквизитДеревоЗначений"); 
КонецПроцедуры

Свернуть и развернуть строки дерева значений

Свернуть и развернуть дочерние строки элемента дерева значений можно с помощью методов Свернуть() и Развернуть().

ВсеЭлементыФормы.ЭлементТаблицаФормы.Свернуть(ИдектификаторСтроки)

• Сворачивает узел в указанной строке дерева.
• ИдектификаторСтроки — идентификатор строки таблицы.

ВсеЭлементыФормы.ЭлементТаблицаФормы.Развернуть(ИдектификаторСтроки, СПодчиненными)

• Разворачивает узел в указанной строке дерева.
• ИдектификаторСтроки — идентификатор строки таблицы.
• СПодчиненными — определяет необходимость раскрытия подчиненных узлов.

&НаКлиенте
Процедура СвернутьТекущуюСтрокуДерева(Команда)
    Элементы.ЭлементДеревоЗначений.Свернуть(
        Элементы.ЭлементДеревоЗначений.ТекущаяСтрока
    );
КонецПроцедуры

&НаКлиенте
Процедура СвернутьВерхниеСтрокиДерева(Команда)
    СтрокиДерева = РеквизитДеревоЗначений.ПолучитьЭлементы();
    Для Каждого ТекущаяСтрока Из СтрокиДерева Цикл
        Элементы.ЭлементДеревоЗначений.Свернуть(
            ТекущаяСтрока.ПолучитьИдентификатор()
        );
    КонецЦикла;
КонецПроцедуры

&НаКлиенте
Процедура СвернутьВсеСтрокиДерева(Команда)
    СтрокиДерева = РеквизитДеревоЗначений.ПолучитьЭлементы();
    СвернутьДочерниеСтрокиДерева(СтрокиДерева); 
КонецПроцедуры
 
&НаКлиенте
Процедура СвернутьДочерниеСтрокиДерева(СтрокиДерева)
    Для Каждого ТекущаяСтрока Из СтрокиДерева Цикл
        ДочерниеСтроки = ТекущаяСтрока.ПолучитьЭлементы();
        // рекурсивный вызов процедуры СвернутьДочерниеСтрокиДерева()
        СвернутьДочерниеСтрокиДерева(ДочерниеСтроки);
        Элементы.ЭлементДеревоЗначений.Свернуть(
            ТекущаяСтрока.ПолучитьИдентификатор()
        );
    КонецЦикла; 
КонецПроцедуры

&НаКлиенте
Процедура РазвернутьТекущуюСтрокуДерева(Команда)
    Элементы.ЭлементДеревоЗначений.Развернуть(
        Элементы.ЭлементДеревоЗначений.ТекущаяСтрока, Истина
    );
КонецПроцедуры

&НаКлиенте
Процедура РазвернутьВсеСтрокиДерева(Команда)
    СтрокиДерева = РеквизитДеревоЗначений.ПолучитьЭлементы();
    Для Каждого ТекущаяСтрока Из СтрокиДерева Цикл
        Элементы.ЭлементДеревоЗначений.Развернуть(
            ТекущаяСтрока.ПолучитьИдентификатор(), Истина
        );
    КонецЦикла;
КонецПроцедуры

ДанныеФормыДерево.ПолучитьЭлементы()

ДанныеФормыЭлементДерева.ПолучитьЭлементы()

Удалить строку и очистить дерево значений

&НаКлиенте
Процедура УдалитьСтрокуДереваЗначений(Команда)
    УдалитьСтрокуДереваЗначенийНаСервере();
КонецПроцедуры

&НаСервере
Процедура УдалитьСтрокуДереваЗначенийНаСервере()
    ДеревоЗначений = РеквизитФормыВЗначение("РеквизитДеревоЗначений");
    // удаляем первую строку дерева значений
    ДеревоЗначений.Строки.Удалить(0);
    ЗначениеВРеквизитФормы(ДеревоЗначений, "РеквизитДеревоЗначений");
КонецПроцедуры

&НаКлиенте
Процедура ОчиститьДеревоЗначений(Команда)
    ОчиститьДеревоЗначенийНаСервере();
КонецПроцедуры

&НаСервере
Процедура ОчиститьДеревоЗначенийНаСервере()
    ДеревоЗначений = РеквизитФормыВЗначение("РеквизитДеревоЗначений");
    ДеревоЗначений.Строки.Очистить();
    ЗначениеВРеквизитФормы(ДеревоЗначений, "РеквизитДеревоЗначений");
КонецПроцедуры

Поиск в дереве значений

Среди наиболее часто используемых методов стоит отметить метод Найти() коллекции строк дерева значений.

КоллекцияСтрокДереваЗначений.Найти(Значение, Колонки, ВключатьПодчиненные)

• Значение (обязательный, тип Произвольный). Искомое значение.
• Колонки (необязательный, тип Строка). Список имен колонок, в которых будет осуществляться поиск, разделенных запятыми. Если параметр не указан, поиск осуществляется по всем колонкам дерева. Значение по умолчанию — Пустая строка.
• ВключатьПодчиненные (необязательный, тип Булево). Определяет, будут ли участвовать в поиске строки подчиненных коллекций (если таковые имеются). Если Истина — строки подчиненных коллекций участвуют в поиске. Значение по умолчанию — Ложь.

Метод осуществляет поиск значения в дереве в указанных колонках коллекции строк дерева значений. Возвращает строку (тип СтрокаДереваЗначений), которая содержит искомое значение. Если значение не найдено, то возвращается значение Неопределено. Предназначен для поиска уникальных значений.

&НаКлиенте
Процедура НайтиСтрокуДереваЗначений(Команда)
    ЗаполнитьТабличноеПолеНаСервере();
    НайтиСтрокуДереваЗначенийНаСервере();
КонецПроцедуры

&НаСервере
Процедура НайтиСтрокуДереваЗначенийНаСервере()
    ДеревоЗначений = РеквизитФормыВЗначение("РеквизитДеревоЗначений");
    РезультатПоиска = ДеревоЗначений.Строки.Найти(
        ИскомоеЗначение,
        "ПерваяКолонка,ВтораяКолонка",
        Истина
    );
    Если РезультатПоиска <> Неопределено Тогда
        Сообщить(
            "Первая колонка: " + РезультатПоиска.ПерваяКолонка +
            ", Вторая колонка: " + РезультатПоиска.ВтораяКолонка
        );
    Иначе
        Сообщить("Ничего не найдено");
    КонецЕсли;
КонецПроцедуры

&НаСервере
Процедура ЗаполнитьТабличноеПолеНаСервере()
    Запрос = Новый Запрос();
    Запрос.Текст = 
        "ВЫБРАТЬ
        |    Номенклатура.Наименование КАК ПерваяКолонка,
        |    Номенклатура.Код КАК ВтораяКолонка
        |ИЗ
        |    Справочник.Номенклатура КАК Номенклатура
        |УПОРЯДОЧИТЬ ПО
        |    ПерваяКолонка ИЕРАРХИЯ";
    ДеревоЗначений = Запрос.Выполнить().Выгрузить(
        ОбходРезультатаЗапроса.ПоГруппировкамСИерархией
    );
    ЗначениеВРеквизитФормы(ДеревоЗначений, "РеквизитДеревоЗначений");
КонецПроцедуры

Поиск:
1С:Предприятие • Дерево значений • Иерархия • Коллекция • Таблица формы • Типы данных • Управляемая форма